# Hurry Curry! - a game about cooking
# Copyright (C) 2025 Hurry Curry! contributors
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as published by
# the Free Software Foundation, version 3 of the License only.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.
#
class_name CuttingBoard
extends CounterBase

var board = load("res://map/tiles/cutting_board.tscn").instantiate()
var chopping: AudioStreamPlayer3D = AudioStreamPlayer3D.new()
var acting_players: Array[Player] = []

func _init(ctx: TileFactory.TileCC):
	super(ctx)
	chopping.stream = preload("res://map/tiles/sounds/chop.ogg")
	add_child(chopping)
	base.add_child(board)

func progress(position_: float, speed: float, warn: bool, acting_players_: Array[Player]):
	super(position_, speed, warn, acting_players)
	var knife: Node3D = board.get_node("Knife")
	
	if speed != 0.:
		if not chopping.playing: chopping.play()
		acting_players = acting_players.filter(is_instance_valid) # Some players might have disconnected
		var players_who_stopped := G.unordered_array_difference(acting_players, acting_players_)
		for p: Player in players_who_stopped:
			if p != null: p.character.cutting = false
		for p: Player in acting_players_:
			knife.visible = false
			p.character.cutting = true
	elif speed == 0:
		chopping.stop()
		knife.visible = true
		for p: Player in acting_players:
			p.character.cutting = false
	acting_players = acting_players_

func finish():
	super()
	acting_players = acting_players.filter(is_instance_valid) # Some players might have disconnected
	for p: Player in acting_players:
		p.character.cutting = false
	board.get_node("Knife").visible = true
	chopping.stop()

static func interact_target() -> Vector3:
	return Vector3(0., 0.575, 0.)