# Hurry Curry! - a game about cooking
# Copyright 2024 metamuffin
# Copyright 2024 tpart
# Copyright 2024 BigbrotherNii
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as published by
# the Free Software Foundation, version 3 of the License only.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.
#
extends Menu

@onready var character: Character = $Node3D/Character
@onready var back_button := $VBoxContainer/bottom_panel/back
@onready var map: Map = $Node3D/Map
@onready var username_edit = $VBoxContainer/top_panel/a/username

func _ready():
	super()
	$VBoxContainer/top_panel/a/username.text = Global.get_profile("username")
	character.set_style(Global.get_profile("character_style"), "chef")
	init_map()

func init_map():
	var map_tile = func (t): match t:
		".": return "floor"
		"=": return "counter"
		"s": return "stove"
		"c": return "chair"
		"t": return "table"
		"o": return "oven"
		"#": return "wall"
		_: push_error("unknown tile: ", t)
	var tiles = [
		"...............",
		"###############",
		"=oo==ss===.ctc#",
		"..............#",
		".............=#",
		".............=#",
		".............=#"
	].map(func (l): return Array(l.split("")).map(map_tile))
	var gt = func (e): return null if e[1] >= tiles.size() else null if e[0] >= tiles[e[1]].size() else tiles[e[1]][e[0]]
	var co = Vector2i(floor(tiles[0].size() / 2), floor(tiles.size() - 2))
	for y in tiles.size():
		for x in tiles[y].size():
			map.set_tile(Vector2i(x,y) - co, gt.call([x,y]), [[x,y-1],[x-1,y],[x,y+1],[x+1,y]].map(gt))
	map.flush()

func _input(_event):
	if Input.is_action_just_pressed("ui_cancel"):
		_on_back_pressed()

func _on_back_pressed():
	if username_edit.text == "":
		var popup_data := MenuPopup.Data.new()
		popup_data.text = tr("c.error.empty_username")
		var accept_button := Button.new()
		accept_button.text = tr("c.menu.accept")
		popup_data.buttons = [accept_button]
		await submenu("res://menu/popup.tscn", popup_data)
		return
	
	Global.set_profile("username", username_edit.text)
	Global.save_profile()
	replace_menu("res://menu/main.tscn")

func _on_character_back_pressed():
	modify_style(func m(current_style: Dictionary):
		current_style.color = G.rem_euclid(current_style.color - 1, character.COLORS.size()))

func _on_character_forward_pressed():
	modify_style(func m(current_style: Dictionary):
		current_style.color = G.rem_euclid(current_style.color + 1, character.COLORS.size()))

func _on_headwear_back_pressed() -> void:
	modify_style(func m(current_style: Dictionary):
		current_style.headwear = G.rem_euclid(current_style.headwear - 1, character.headwears.size()))

func _on_headwear_forward_pressed() -> void:
	modify_style(func m(current_style: Dictionary):
		current_style.headwear = G.rem_euclid(current_style.headwear + 1, character.headwears.size()))

func _on_hairstyle_back_pressed() -> void:
	modify_style(func m(current_style: Dictionary):
		current_style.hairstyle = G.rem_euclid(current_style.hairstyle - 1, character.hairstyles.size()))

func _on_hairstyle_forward_pressed() -> void:
	modify_style(func m(current_style: Dictionary):
		current_style.hairstyle = G.rem_euclid(current_style.hairstyle + 1, character.hairstyles.size()))

func modify_style(modifier: Callable):
	var current_style: Dictionary = Global.get_profile("character_style")
	modifier.call(current_style)
	Global.set_profile("character_style", current_style)
	character.set_style(Global.get_profile("character_style"), "chef")