# Hurry Curry! - a game about cooking
# Copyright 2024 tpart
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as published by
# the Free Software Foundation, version 3 of the License only.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.
#
extends Menu
class_name ChatOpen

const CHAT_MESSAGE_SCENE = preload("res://menu/chat/chat_message.tscn")

@onready var messages_container: VBoxContainer = $PanelContainer/MarginContainer/VBoxContainer/ScrollContainerCustom/Messages
@onready var line: LineEdit = $PanelContainer/MarginContainer/VBoxContainer/LineEdit
@onready var game_menu: GameMenu = get_parent()
@onready var game: Game = game_menu.game

func _ready() -> void:
	super()
	for i in game.text_message_history:
		add_message(i[0], i[1])
	
	game.text_message.connect(
		func message(username: String, text: String, _timeout_initial: float, _timeout_remaining: float):
			add_message(username, text)
	)

func _input(event: InputEvent) -> void:
	if Input.is_action_just_pressed("chat"):
		if line.text != "":
			game.mp.send_chat(game.player_id, line.text)
		exit()
	super(event)

func add_message(username: String, message: String):
	var chat_message: ChatMessage = CHAT_MESSAGE_SCENE.instantiate()
	messages_container.add_child(chat_message)
	chat_message.set_message("<%s>" % username, message)