# Hurry Curry! - a game about cooking
# Copyright 2024 tpart
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as published by
# the Free Software Foundation, version 3 of the License only.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.
#
extends Node

var default_input_map = {}
var input_map

func _init():
	default_input_map = get_input_map()
	input_map = default_input_map.duplicate(true)

func get_input_map() -> Dictionary:
	var actions = InputMap.get_actions().filter(func isBuiltIn(k: String): return !k.begins_with("ui_"))
	var kb = {}
	for a in actions:
		var input_events: Array[InputEvent] = InputMap.action_get_events(a).duplicate(true)
		kb[a] = input_events
	return kb

func input_map_to_settings_dictionary(map: Dictionary) -> Dictionary:
	var settings_dict := {}
	for k in map.keys():
		var events = map[k]
		settings_dict[k] = InputSetting.new(k, events)
	return settings_dict

func change_input_map_action(action_name: String, event: InputEvent, save: bool = true):
	if !InputMap.has_action(action_name):
		push_error("Action %s does not exist" % action_name, false)
		return
	# Erase previous keybindings
	var events = InputMap.action_get_events(action_name).duplicate(true)
	InputMap.action_erase_events(action_name)
	# Add new keybindings
	events[0] = event
	for e in events:
		InputMap.action_add_event(action_name, e)
	
	if save:
		# Update input map dictionary
		input_map = get_input_map()
		# Save settings
		Global.set_setting("input_map", input_map.duplicate(true))

func apply_input_map(new_input_map: Dictionary):
	# Load into input map dictionary
	for k in new_input_map.keys():
		input_map[k] = []
		for a in new_input_map[k]:
			input_map[k].append(a)
		print("Loaded keybind: %s with " % k + str(input_map[k]))
	
	# Apply keybindings
	for k in input_map.keys():
		change_input_map_action(k, input_map[k][0], false)

func reset_input_map():
	Global.set_setting("input_map", default_input_map.duplicate())
	apply_input_map(Global.get_setting("input_map"))