# Hurry Curry! - a game about cooking
# Copyright 2024 metamuffin
# Copyright 2024 tpart
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as published by
# the Free Software Foundation, version 3 of the License only.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.
#
extends Menu

const SCROLL_SPEED := 500.

@onready var anim: AnimationPlayer = $AnimationPlayer
@onready var username: LineEdit = $ScrollContainer/Control/TextureRect/PaperMargin/Contents/NameEntry/LineEdit
@onready var character_opts: Container = $ScrollContainer/Control/TextureRect/PaperMargin/Contents/UniformEntry
@onready var sign: AudioStreamPlayer = $Sign
@onready var sign_button: Button = $ScrollContainer/Control/TextureRect/PaperMargin/Contents/Signatures/EmployeeMargin/Sign/Signature
@onready var scroll: ScrollContainer = $ScrollContainer

func _ready():
	anim.play("paper_slide")
	super()

func _process(delta):
	var s = Input.get_axis("rotate_up", "rotate_down")
	scroll.set_deferred("scroll_vertical", scroll.scroll_vertical + s * delta * SCROLL_SPEED)

func _on_sign_pressed():
	var character = -1
	for i in character_opts.get_children().size():
		if character_opts.get_children()[i].button_pressed:
			character = i

	if username.text == "": OS.alert("Name field cannot be empty."); return
	if character == -1: OS.alert("Hairstyle needs to be selected."); return

	sign_button.disabled = true

	sign.play()
	await sign.finished
	anim.play_backwards("paper_slide")
	await anim.animation_finished

	Global.profile["username"] = username.text
	Global.profile["character"] = character

	Global.set_setting("setup_complete", true)
	Global.save_profile()
	Global.save_settings()
	replace_menu("res://menu/main.tscn")