# Hurry Curry! - a game about cooking
# Copyright 2024 metamuffin
# Copyright 2024 tpart
# Copyright 2024 nokoe
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as published by
# the Free Software Foundation, version 3 of the License only.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.
#
extends Menu

const SCROLL_SPEED := 500.

var character := -1

@onready var anim: AnimationPlayer = $AnimationPlayer
@onready var username: LineEdit = $ScrollContainer/Control/TextureRect/PaperMargin/Contents/NameEntry/LineEdit
@onready var sign_sound: AudioStreamPlayer = $Sign
@onready var sign_button: Button = $ScrollContainer/Control/TextureRect/PaperMargin/Contents/Signatures/EmployeeMargin/Sign/Signature
@onready var scroll: ScrollContainer = $ScrollContainer
@onready var select_uniform: HBoxContainer = $ScrollContainer/Control/TextureRect/PaperMargin/Contents/SelectUniform
@onready var skip_tutorial: CheckBox = $ScrollContainer/Control/TextureRect/PaperMargin/Contents/SelectExperience/CheckBox

func _ready():
	anim.play("paper_slide")
	var button_group := ButtonGroup.new()
	for i in range(3):
		var preview: HairstylePreview = preload("res://menu/hairstyle_preview.tscn").instantiate()
		select_uniform.add_child(preview)
		preview.setup(i, button_group)
		preview.selected.connect(_character_selected)
		if i < 2:
			var spacer = Control.new()
			spacer.size_flags_vertical = Control.SIZE_EXPAND
			spacer.custom_minimum_size.x = 50
			select_uniform.add_child(spacer)
			
	# Enable msaa 2D for this scene
	Global.get_viewport().msaa_2d = Viewport.MSAA_4X
	
	super()

func _character_selected(idx: int):
	character = idx

func _process(delta):
	var s = Input.get_axis("rotate_up", "rotate_down")
	scroll.set_deferred("scroll_vertical", scroll.scroll_vertical + s * delta * SCROLL_SPEED)


func check():
	if username.text == "": return tr("c.error.empty_username")
	if character == -1: return tr("c.error.select_hairstyle")
	return null

func _on_sign_pressed():
	if check() != null:
		var popup_data := MenuPopup.Data.new()
		popup_data.text = check()
		var accept_button := Button.new()
		accept_button.text = tr("c.menu.accept")
		popup_data.buttons = [accept_button]
		await submenu("res://menu/popup.tscn", popup_data)
		return

	sign_button.disabled = true

	sign_sound.play()
	await sign_sound.finished
	anim.play_backwards("paper_slide")
	await anim.animation_finished

	Global.set_profile("username", username.text)
	if skip_tutorial.button_pressed:
		for k in Global.profile["hints"].keys():
			Global.set_hint(k, true)
	Global.save_profile()

	Global.set_setting("gameplay.hints_started", skip_tutorial.button_pressed)
	Global.set_setting("gameplay.tutorial_disabled", skip_tutorial.button_pressed)
	Global.set_setting("gameplay.setup_completed", true)
	Global.save_settings()
	
	Global.get_viewport().msaa_2d = Viewport.MSAA_DISABLED
	
	replace_menu("res://menu/main.tscn")