# Hurry Curry! - a game about cooking
# Copyright (C) 2025 Hurry Curry! contributors
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as published by
# the Free Software Foundation, version 3 of the License only.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.
#
class_name RollingBoard
extends CounterBase

var board = load("res://map/tiles/rolling_board.tscn")
var rolling: AudioStreamPlayer3D = AudioStreamPlayer3D.new()
var acting_players: Array[Player]

func _init(ctx: TileFactory.TileCC):
	super(ctx, board)
	rolling.stream = preload("res://map/tiles/sounds/roll.ogg")
	rolling.volume_db = -10
	add_child(rolling)

func progress(position_: float, speed: float, warn: bool, acting_players_: Array[Player]):
	super(position_, speed, warn, acting_players_)
	var pin: Node3D = base.get_node("RollingBoard").get_node("RollingPin")
	
	if speed != 0.:
		if not rolling.playing: rolling.play()
		acting_players = acting_players.filter(is_instance_valid) # Some players might have disconnected
		var players_who_stopped := G.unordered_array_difference(acting_players, acting_players_)
		for p: Player in players_who_stopped:
			if p != null: p.character.rolling = false
		for p: Player in acting_players_:
			pin.visible = false
			p.character.rolling = true
	elif speed == 0:
		rolling.stop()
		pin.visible = true
		for p: Player in acting_players:
			p.character.rolling = false
	acting_players = acting_players_

func finish():
	super()
	acting_players = acting_players.filter(is_instance_valid) # Some players might have disconnected
	for p: Player in acting_players:
		p.character.rolling = false
	base.get_node("RollingBoard").get_node("RollingPin").visible = true
	rolling.stop()

static func interact_target() -> Vector3:
	return Vector3(0., 0.575, 0.)
