# Hurry Curry! - a game about cooking
# Copyright (C) 2025 Hurry Curry! contributors
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as published by
# the Free Software Foundation, version 3 of the License only.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.
#
extends Menu

@onready var character: Character = $Node3D/Character
@onready var back_button := $VBoxContainer/bottom_panel/back
@onready var username_edit = $VBoxContainer/top_panel/a/username

func _ready():
	super()
	$VBoxContainer/top_panel/a/username.text = Profile.read("username")
	character.set_style(Profile.read("character_style"), "chef")

func _menu_music(): Sound.set_music("reflets-dans-leau", -3, true)

func exit():
	if username_edit.text == "":
		var popup_data := MenuPopup.Data.new()
		popup_data.text = tr("c.error.empty_username")
		var accept_button := Button.new()
		accept_button.text = tr("c.menu.accept")
		popup_data.buttons = [accept_button]
		await submenu("res://gui/menus/popup.tscn", popup_data)
		return
	Profile.write("username", username_edit.text)
	super()

func _on_character_back_pressed():
	modify_style(func m(current_style: Dictionary):
		current_style.color = G.rem_euclid(current_style.color - 1, character.COLORS.size()))

func _on_character_forward_pressed():
	modify_style(func m(current_style: Dictionary):
		current_style.color = G.rem_euclid(current_style.color + 1, character.COLORS.size()))

func _on_headwear_back_pressed() -> void:
	modify_style(func m(current_style: Dictionary):
		current_style.headwear = G.rem_euclid(current_style.headwear - 1, character.headwears.size()))

func _on_headwear_forward_pressed() -> void:
	modify_style(func m(current_style: Dictionary):
		current_style.headwear = G.rem_euclid(current_style.headwear + 1, character.headwears.size()))

func _on_hairstyle_back_pressed() -> void:
	modify_style(func m(current_style: Dictionary):
		current_style.hairstyle = G.rem_euclid(current_style.hairstyle - 1, character.hairstyles.size()))

func _on_hairstyle_forward_pressed() -> void:
	modify_style(func m(current_style: Dictionary):
		current_style.hairstyle = G.rem_euclid(current_style.hairstyle + 1, character.hairstyles.size()))

func modify_style(modifier: Callable):
	var current_style: Dictionary = Profile.read("character_style")
	modifier.call(current_style)
	Profile.write("character_style", current_style)
	character.set_style(Profile.read("character_style"), "chef")
