# Hurry Curry! - a game about cooking
# Copyright (C) 2025 Hurry Curry! contributors
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as published by
# the Free Software Foundation, version 3 of the License only.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.
#
class_name CuttingBoard
extends CounterBase

var board = load("res://map/tiles/cutting_board.tscn").instantiate()
var chopping: AudioStreamPlayer3D = AudioStreamPlayer3D.new()
var acting_player

func _init(ctx: TileFactory.TileCC):
	super(ctx)
	chopping.stream = preload("res://map/tiles/sounds/chop.ogg")
	add_child(chopping)
	base.add_child(board)

func progress(position_: float, speed: float, warn: bool, acting_player_):
	super(position_, speed, warn, acting_player)
	var knife: Node3D = board.get_node("Knife")
	acting_player = acting_player_
	
	if not chopping.playing and speed != 0.:
		chopping.play()
		if acting_player != null:
			knife.visible = false
			var acting_character: Character = acting_player.character
			acting_character.cutting = true
	elif speed == 0:
		chopping.stop()
		knife.visible = true
		if acting_player != null:
			var acting_character: Character = acting_player.character
			acting_character.cutting = false

func finish():
	super()
	if is_instance_valid(acting_player):
		var acting_character: Character = acting_player.character
		acting_character.cutting = false
	board.get_node("Knife").visible = true
	chopping.stop()

static func interact_target() -> Vector3:
	return Vector3(0., 0.575, 0.)
