# Hurry Curry! - a game about cooking
# Copyright (C) 2025 Hurry Curry! contributors
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as published by
# the Free Software Foundation, version 3 of the License only.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.
#
class_name GameSetting
extends Object

var default
var key: String
var nskey: String


func _init(new_id: String, new_default = null):
	default = new_default
	key = new_id

func set_parent(parent: GameSetting):
	if parent != null: key = parent.key + "." + key
	nskey = "c.settings." + key

func create_row():
	var row = preload("res://gui/menus/settings/settings_row.tscn").instantiate()
	row.description = tr(nskey)
	if hide_reset(): row.hide_reset = true
	else:
		row.reset.connect(func(): Settings.write(key, default))
		Settings.hook_changed_init(key, row, func (_value):
			if is_instance_valid(row): row.set_reset_disabled(is_default())
		)
	return row

func hide_reset(): return false

func is_default():
	return Settings.read(key) == default

func load(d: Dictionary):
	if d.has(key) && typeof(d[key]) == typeof(default):
		Settings.write_unchecked(key, d[key])
	elif default != null:
		Settings.write_unchecked(key, default)

func save(d: Dictionary):
	var value = Settings.read(key)
	if value == default: return
	d[key] = value
