# Hurry Curry! - a game about cooking
# Copyright (C) 2026 Hurry Curry! Contributors
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as published by
# the Free Software Foundation, version 3 of the License only.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.
#
extends VBoxContainer
class_name InputValueNode

var value = []
var listening := false

signal changed()

@onready var actions_container: VBoxContainer = $ActionsContainer
@onready var add_button: Button = $Add
@onready var add_text = add_button.text

func _ready():
	update()

func update(fix_focus: bool = false):
	for c in actions_container.get_children():
		c.queue_free()
	
	for e: InputEvent in value:
		var description: String = InputManager.display_input_event(e)
		var button := Button.new()
		
		button.text = description
		button.pressed.connect(erase_event.bind(e))
		actions_container.add_child(button)
	
	if fix_focus:
		add_button.grab_focus()

func erase_event(e: InputEvent):
	value.erase(e)
	changed.emit()

func _input(e: InputEvent):
	if listening:
		if e is InputEventKey or e is InputEventMouseButton or e is InputEventJoypadButton or e is InputEventJoypadMotion:
			# Check if key was already added
			for e2 in value:
				if InputSetting.events_equal(e, e2): return
			
			value.append(e)
			_on_add_pressed()
			changed.emit()

func _on_add_pressed() -> void:
	listening = not listening
	add_button.text = tr("c.settings.input.press_any_key") if listening else add_text
