# Maintainer: metamuffin <metamuffin@disroot.org>

pkgname=fastbangs-git
pkgver=r91.0ece6f0
pkgrel=4
pkgdesc="A search engine redirect service"
arch=('x86_64')
url="https://codeberg.org/lialenck/fastbangs"
license=('AGPL-3.0-only')
makedepends=('esbuild' 'sassc' 'stack-static' 'make')
backup=('etc/fastbangs.yaml')
install='fastbangs.install'
source=("git+https://codeberg.org/lialenck/fastbangs"
        "fastbangs.service"
        "sysusers.conf")
sha256sums=("SKIP"
            "SKIP"
            "SKIP")

pkgver() {
    cd "fastbangs"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
    cd "fastbangs"
    make frontend/fuzzysort.js
    stack setup
}
build() {
    cd "fastbangs"
    make
}
package() {
    install -Dm755 fastbangs/deploy/fastbangs "$pkgdir/usr/bin/fastbangs"
    install -Dm644 fastbangs/LICENSE.agpl "$pkgdir/usr/share/licenses/fastbangs/COPYING"
    install -Dm644 sysusers.conf "$pkgdir/usr/lib/sysusers.d/fastbangs.conf"
    install -Dm644 fastbangs.service "$pkgdir/usr/lib/systemd/system/fastbangs.service"
    install -Dm644 fastbangs/fastbangs.yaml "$pkgdir/etc/fastbangs.yaml"
}