# Maintainer: metamuffin <metamuffin@disroot.org>

pkgname=hurrycurry-pixel-client-git
pkgver=r1978.f722b8f
pkgrel=1
pkgdesc="A game about cooking (pixel client)"
arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
url="https://codeberg.org/hurrycurry/hurrycurry"
license=('AGPL3')
depends=('sdl2')
makedepends=('rustup' 'sdl2' 'sdl2_image')
conflics=('hurrycurry-pixel-client')
provides=('hurrycurry-pixel-client')
source=("git+https://codeberg.org/hurrycurry/hurrycurry.git"
        "hurrycurry-pixel-client.desktop")
sha256sums=("SKIP"
            "SKIP")

pkgver() {
    cd "hurrycurry"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
    cd "hurrycurry"
    rustup default nightly
    cargo +nightly fetch --locked --target "$CHOST"
}
build() {
    cd "hurrycurry"
    make pixel-client
    cargo build --release --bin pixelcurry --target "$CHOST"
}
package() {
    install -Dm755 hurrycurry/target/$CHOST/release/pixelcurry "$pkgdir/usr/bin/pixelcurry"
    install -Dm644 hurrycurry-pixel-client.desktop "$pkgdir/usr/share/applications/hurrycurry-pixel-client.desktop"
    install -Dm644 hurrycurry/COPYING "$pkgdir/usr/share/licenses/hurrycurry-pixel-client/COPYING"
    install -Dm644 hurrycurry/pixel-client/icon.png "$pkgdir/usr/share/icons/hicolor/512x512/apps/pixelcurry.png"
}