# Maintainer: metamuffin <metamuffin@disroot.org>

pkgname=hurrycurry-server-git
pkgver=r2036.03cbd71
pkgrel=1
pkgdesc="A game about cooking (server)"
arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
url="https://codeberg.org/hurrycurry/hurrycurry"
license=('AGPL3')
conflics=('hurrycurry-server')
provides=('hurrycurry-server')
makedepends=('rustup' 'deno' 'graphviz' 'godot' 'esbuild')
source=("git+https://codeberg.org/hurrycurry/hurrycurry.git"
        "hurrycurry.service"
        "hurrycurry-registry.service"
        "hurrycurry.yaml"
        "tmpfiles.conf"
        "sysusers.conf")
sha256sums=("SKIP"
            "SKIP"
            "SKIP"
            "SKIP"
            "SKIP"
            "SKIP")

pkgver() {
    cd "hurrycurry"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
    cd "hurrycurry"
    rustup default nightly
    cargo +nightly fetch --locked --target "$CHOST"
}
build() {
    cd "hurrycurry"
    cargo +nightly build --frozen --release --target "$CHOST" --bin hurrycurry-server
    cargo +nightly build --frozen --release --target "$CHOST" --bin hurrycurry-replaytool
    cargo +nightly build --frozen --release --target "$CHOST" --bin hurrycurry-registry
    cargo +nightly build --frozen --release --target "$CHOST" --bin hurrycurry-discover
    make -C data all
    make -C test-client
    make -C data recipes/default.svg
}
package() {
    install -Dm755 hurrycurry/target/$CHOST/release/hurrycurry-server "$pkgdir/usr/bin/hurrycurry-server"
    install -Dm755 hurrycurry/target/$CHOST/release/hurrycurry-replaytool "$pkgdir/usr/bin/hurrycurry-replaytool"
    install -Dm755 hurrycurry/target/$CHOST/release/hurrycurry-registry "$pkgdir/usr/bin/hurrycurry-registry"
    install -Dm755 hurrycurry/target/$CHOST/release/hurrycurry-discover "$pkgdir/usr/bin/hurrycurry-discover"
    install -Dm644 hurrycurry.service "$pkgdir/usr/lib/systemd/system/hurrycurry.service"
    install -Dm644 hurrycurry-registry.service "$pkgdir/usr/lib/systemd/system/hurrycurry-registry.service"
    install -Dm644 sysusers.conf "$pkgdir/usr/lib/sysusers.d/hurrycurry.conf"
    install -Dm644 tmpfiles.conf "$pkgdir/usr/lib/tmpfiles.d/hurrycurry.conf"
    install -Dm644 hurrycurry/COPYING "$pkgdir/usr/share/licenses/hurrycurry-server/COPYING"
    install -Dm664 hurrycurry/test-client/main.js "$pkgdir/usr/share/hurrycurry/test-client/main.js"
    install -Dm664 hurrycurry/test-client/index.html "$pkgdir/usr/share/hurrycurry/test-client/index.html"
    install -dm755 "$pkgdir/usr/share/hurrycurry/test-client/locale"
    install -Dm664 -t "$pkgdir/usr/share/hurrycurry/test-client/locale" hurrycurry/test-client/locale/*
    install -Dm644 hurrycurry/data/index.yaml "$pkgdir/usr/share/hurrycurry/data/index.yaml"
    install -Dm664 -t "$pkgdir/usr/share/hurrycurry/data/recipes" hurrycurry/data/recipes/*.yaml 
    install -Dm664 -t "$pkgdir/usr/share/hurrycurry/data/maps" hurrycurry/data/maps/*.yaml 
    install -Dm664 hurrycurry/data/book.json "$pkgdir/usr/share/hurrycurry/data/book.json" 
    install -Dm664 -t "$pkgdir/usr/share/doc/hurrycurry/recipes" hurrycurry/data/recipes/*.svg 
}