# Maintainer: metamuffin <metamuffin@disroot.org>

pkgname=isdad-git
pkgver=r52.eb16e80
pkgrel=1
pkgdesc="Task queue server for isda"
arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
url="https://codeberg.org/metamuffin/isda"
license=('AGPL3')
conflics=('isdad')
provides=('isdad')
makedepends=('rustup')
source=("git+https://codeberg.org/metamuffin/isda.git"
        "isdad.service"
        "sysusers.conf")
sha256sums=("SKIP"
            "SKIP"
            "SKIP")

rust_chost() {
	sed -e "s/-pc-linux/-unknown-linux/" -e "s/armv7l-/armv7-/" <<< "$CHOST"
}

pkgver() {
    cd "isda"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
    cd "isda"
    cargo +nightly fetch --locked --target "$(rust_chost)"
}
build() {
    cd "isda"
    cargo +nightly build --frozen --release --target "$(rust_chost)"
}
package() {
    install -Dm755 "isda/target/$(rust_chost)/release/isdad" "$pkgdir/usr/bin/isdad"
    install -Dm644 sysusers.conf "$pkgdir/usr/lib/sysusers.d/isdad.conf"
    install -Dm644 isdad.service "$pkgdir/usr/lib/systemd/system/isdad.service"
    install -Dm644 isda/COPYING "$pkgdir/usr/share/licenses/isdad/COPYING"
}