# Maintainer: metamuffin <metamuffin@disroot.org>

pkgname=keks-meet-server-git
pkgver=r417.dba8f58
pkgrel=1
pkgdesc="Server for keks-meet, a simple and secure conferencing application for the web."
arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
url="https://codeberg.org/metamuffin/keks-meet"
license=('AGPL3')
makedepends=('rustup' 'esbuild')
conflics=('keks-meet-server')
provides=('keks-meet-server')
backup=('etc/keks-meet-server.toml')
source=("git+https://codeberg.org/metamuffin/keks-meet.git"
        "keks-meet-server.service"
        "sysusers.conf")
sha256sums=("SKIP"
            "SKIP"
            "SKIP")

rust_chost() {
	sed -e "s/-pc-linux/-unknown-linux/" -e "s/armv7l-/armv7-/" <<< "$CHOST"
}

pkgver() {
    cd "keks-meet"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
    cd "keks-meet"
    cargo fetch --locked --target "$(rust_chost)"
}
build() {
    cd "keks-meet"
    make client-build
    cargo build --frozen --release --bin keks-meet-server --target "$(rust_chost)"
}
package() {
    install -Dm755 keks-meet/target/$(rust_chost)/release/keks-meet-server "$pkgdir/usr/bin/keks-meet-server"
    install -Dm644 sysusers.conf "$pkgdir/usr/lib/sysusers.d/keks-meet-server.conf"
    install -Dm644 keks-meet-server.service "$pkgdir/usr/lib/systemd/system/keks-meet-server.service"
    install -Dm644 keks-meet/COPYING "$pkgdir/usr/share/licenses/keks-meet/COPYING"
    install -Dm644 keks-meet/config/default.toml "$pkgdir/etc/keks-meet-server.toml"
}