# Maintainer: metamuffin <metamuffin@disroot.org>

pkgname=meta-adservices-git
pkgver=r20.aab1ddb
pkgrel=1
pkgdesc="Funny adservice."
arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
url="https://codeberg.org/metamuffin/meta-adservices"
license=('AGPL-3.0-only')
depends=()
makedepends=('rustup')
backup=('etc/meta_adservices.toml')
source=("git+https://codeberg.org/metamuffin/meta-adservices.git"
        "meta_adservices.service"
        "meta_adservices.toml"
        "sysusers.conf")
sha256sums=("SKIP"
            "SKIP"
            "SKIP"
            "SKIP")

rust_chost() {
	sed -e "s/-pc-linux/-unknown-linux/" -e "s/armv7l-/armv7-/" <<< "$CHOST"
}

pkgver() {
    cd "meta-adservices"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
    cd "meta-adservices"
    rustup default nightly
    cargo +nightly fetch --target "$(rust_chost)"
}
build() {
    cd "meta-adservices"
    cargo +nightly build --release --target "$(rust_chost)"
}
package() {
    install -Dm755 meta-adservices/target/"$(rust_chost)"/release/meta-adservices "$pkgdir/usr/bin/meta-adservices"
    install -Dm644 meta-adservices/COPYING "$pkgdir/usr/share/licenses/meta-adservices/COPYING"
    install -Dm644 sysusers.conf "$pkgdir/usr/lib/sysusers.d/meta-adservices.conf"
    install -Dm644 meta_adservices.service "$pkgdir/usr/lib/systemd/system/meta_adservices.service"
    install -Dm644 meta_adservices.toml "$pkgdir/etc/meta_adservices.toml"
    mkdir -p "$pkgdir/var/lib/meta_adservices"
}