# Maintainer: metamuffin <metamuffin@disroot.org>

pkgname=metamuffin-website-git
pkgver=r76.fbc308f
pkgrel=1
pkgdesc="metamuffins personal webpage"
arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
url="https://codeberg.org/metamuffin/metamuffin-website"
license=('AGPL3')
makedepends=('rustup')
source=("git+https://codeberg.org/metamuffin/metamuffin-website.git"
        "metamuffin-website.service"
        "sysusers.conf")
sha256sums=("SKIP"
            "SKIP"
            "SKIP")

rust_chost() {
	sed -e "s/-pc-linux/-unknown-linux/" -e "s/armv7l-/armv7-/" <<< "$CHOST"
}

pkgver() {
    cd "metamuffin-website"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
    cd "metamuffin-website"
    rustup default nightly
    cargo +nightly fetch --locked --target "$(rust_chost)"
}
build() {
    cd "metamuffin-website"
    cargo +nightly build --frozen --release --target "$(rust_chost)"
}
package() {
    mkdir -p "$pkgdir/usr/share/metamuffin-website"
    install -Dm755 metamuffin-website/target/$(rust_chost)/release/metamuffin-website "$pkgdir/usr/bin/metamuffin-website"
    install -Dm644 metamuffin-website.service "$pkgdir/usr/lib/systemd/system/metamuffin-website.service"
    install -Dm644 sysusers.conf "$pkgdir/usr/lib/sysusers.d/metamuffin-website.conf"
    install -Dm644 metamuffin-website/COPYING "$pkgdir/usr/share/licenses/metamuffin-website/COPYING"
}