1 files changed, 29 insertions, 0 deletions
diff --git a/code/src/markdown/parser.pest b/code/src/markdown/parser.pest
new file mode 100644
index 0000000..22563d4
--- /dev/null
+++ b/code/src/markdown/parser.pest
@@ -0,0 +1,29 @@
+file = _{ SOI ~ NEWLINE* ~ (block ~ NEWLINE*)* ~ EOI }
+
+block = { code_block | latex_block | header | unordered_list | ordered_list | paragraph }
+    header = { "#"{1,6} ~ span }
+    unordered_list = { unordered_list_item+ }
+        unordered_list_item = { "-" ~ span ~ NEWLINE }
+    ordered_list = { ordered_list_item+ }
+        ordered_list_item = { ASCII_DIGIT+ ~ "." ~ span ~ NEWLINE }
+    paragraph = { span }
+    code_block = { "```" ~ code_block_lang ~ NEWLINE ~ code_block_inner ~ "```" }
+        code_block_lang = { ASCII_ALPHANUMERIC* }
+        code_block_inner = { (!"```" ~ ANY)* }
+    latex_block = { "$$" ~ latex_block_inner ~ "$$" }
+        latex_block_inner = { (!"$$" ~ ANY)* }
+  
+
+span = { (style_bold | style_italic | style_code | inline_latex | hyperlink | text)+ }
+    style_bold = { "**" ~ span ~ "**" }
+    style_italic = { "_" ~ span ~ "_" }
+    style_code = { "`" ~ code_inner ~ "`" }
+        code_inner = { (!"`" ~ ANY)+ }
+    inline_latex = { "$" ~ latex_inner ~ "$" }
+        latex_inner = { (!"$" ~ ANY)+ }
+    hyperlink = { "[" ~ hyperlink_label ~ "](" ~ hyperlink_location ~ ")" }
+        hyperlink_label = { span }
+        hyperlink_location = { (!")" ~ANY)+ }
+    
+    text = { (!("[" | "]" | "*" | "_" | "`" | "$" | ("\n" ~ forbidden_span_wrap)) ~ ANY)+ }
+    forbidden_span_wrap = _{ "\n" | "-" | ASCII_DIGIT+ ~ "." }