add existing pkgbuilds

1 files changed, 42 insertions, 0 deletions

diff --git a/conduit-git/PKGBUILD b/conduit-git/PKGBUILD
new file mode 100644
index 0000000..c5dbe93
--- /dev/null
+++ b/conduit-git/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: metamuffin <metamuffin@disroot.org>
+
+pkgname=conduit-git
+pkgver=r2330.be1b8b68
+pkgrel=1
+pkgdesc="conduit matrix homeserver"
+arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
+url="https://codeberg.org/metamuffin/conduit"
+license=('AGPL3')
+depends=('gcc-libs')
+makedepends=('rustup' 'clang')
+backup=('etc/conduit.toml')
+source=("git+https://gitlab.com/famedly/conduit.git"
+        "conduit.service"
+        "config.toml"
+        "tmpfiles.conf"
+        "sysusers.conf")
+sha256sums=("SKIP"
+            "SKIP"
+            "SKIP"
+            "SKIP"
+            "SKIP")
+pkgver() {
+    cd "conduit"
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+prepare() {
+    cd "conduit"
+    cargo fetch --locked --target "$CHOST"
+}
+build() {
+    cd "conduit"
+    cargo build --frozen --release --target "$CHOST"
+}
+package() {
+    install -Dm755 conduit/target/$CHOST/release/conduit "$pkgdir/usr/bin/conduit"
+    install -Dm644 config.toml "$pkgdir/etc/conduit.toml"
+    install -Dm644 sysusers.conf "$pkgdir/usr/lib/sysusers.d/conduit.conf"
+    install -Dm644 tmpfiles.conf "$pkgdir/usr/lib/tmpfiles.d/conduit.conf"
+    install -Dm644 conduit.service "$pkgdir/usr/lib/systemd/system/conduit.service"
+    install -Dm644 conduit/LICENSE "$pkgdir/usr/share/licenses/conduit/LICENSE"
+}