summaryrefslogtreecommitdiff
path: root/conduit-git/PKGBUILD
blob: e650f2b696d9a636d0db6ff159fc849cff979b9b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: metamuffin <metamuffin@disroot.org>

pkgname=conduit-git
pkgver=r2406.e952522a
pkgrel=1
pkgdesc="conduit matrix homeserver"
arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
url="https://codeberg.org/metamuffin/conduit"
license=('AGPL3')
depends=('gcc-libs')
makedepends=('rustup' 'clang')
backup=('etc/conduit.toml')
source=("git+https://gitlab.com/famedly/conduit.git"
        "conduit.service"
        "config.toml"
        "tmpfiles.conf"
        "sysusers.conf")
sha256sums=("SKIP"
            "SKIP"
            "SKIP"
            "SKIP"
            "SKIP")
pkgver() {
    cd "conduit"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
    cd "conduit"
    cargo fetch --locked --target "$CHOST"
}
build() {
    cd "conduit"
    cargo build --frozen --release --target "$CHOST"
}
package() {
    install -Dm755 conduit/target/$CHOST/release/conduit "$pkgdir/usr/bin/conduit"
    install -Dm644 config.toml "$pkgdir/etc/conduit.toml"
    install -Dm644 sysusers.conf "$pkgdir/usr/lib/sysusers.d/conduit.conf"
    install -Dm644 tmpfiles.conf "$pkgdir/usr/lib/tmpfiles.d/conduit.conf"
    install -Dm644 conduit.service "$pkgdir/usr/lib/systemd/system/conduit.service"
    install -Dm644 conduit/LICENSE "$pkgdir/usr/share/licenses/conduit/LICENSE"
}