blob: b0def43d42181d23ae0ffe4db1234be94e550ce8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: metamuffin <metamuffin@disroot.org>
pkgname=gpn-tron-git
pkgver=r21.12f974f
pkgrel=1
pkgdesc="GPN-Tron Rust rewrite"
arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
url="https://codeberg.org/metamuffin/gpn-tron-rust"
license=('AGPL-3.0-only')
makedepends=('rustup' 'esbuild')
backup=('etc/gpn-tron.toml')
source=("gpn-tron::git+https://codeberg.org/metamuffin/gpn-tron-rust"
"gpn-tron.service"
"gpn-tron.toml"
"sysusers.conf")
sha256sums=("SKIP"
"SKIP"
"SKIP"
"SKIP")
pkgver() {
cd "gpn-tron"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "gpn-tron"
cargo +nightly fetch --locked --target "$CHOST"
}
build() {
cd "gpn-tron"
cargo +nightly build --frozen --release --target "$CHOST"
}
package() {
install -Dm755 gpn-tron/target/$CHOST/release/gpn-tron "$pkgdir/usr/bin/gpn-tron"
install -Dm644 gpn-tron/COPYING "$pkgdir/usr/share/licenses/gpn-tron/COPYING"
install -Dm644 sysusers.conf "$pkgdir/usr/lib/sysusers.d/gpn-tron.conf"
install -Dm644 gpn-tron.service "$pkgdir/usr/lib/systemd/system/gpn-tron.service"
install -Dm644 gpn-tron.toml "$pkgdir/etc/gpn-tron.toml"
}
|