reorganize client gui files

1 files changed, 74 insertions, 0 deletions

diff --git a/client/gui/menus/settings/input/input_value_node.gd b/client/gui/menus/settings/input/input_value_node.gd
new file mode 100644
index 00000000..7c718e25
--- /dev/null
+++ b/client/gui/menus/settings/input/input_value_node.gd
@@ -0,0 +1,74 @@
+# Hurry Curry! - a game about cooking
+# Copyright (C) 2025 Hurry Curry! contributors
+#
+# This program is free software: you can redistribute it and/or modify
+# it under the terms of the GNU Affero General Public License as published by
+# the Free Software Foundation, version 3 of the License only.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU Affero General Public License for more details.
+#
+# You should have received a copy of the GNU Affero General Public License
+# along with this program.  If not, see <https://www.gnu.org/licenses/>.
+#
+extends VBoxContainer
+class_name InputValueNode
+
+var value: Array[InputEvent] = []
+var listening := false
+
+signal changed()
+
+@onready var actions_container: VBoxContainer = $ActionsContainer
+@onready var add_button: Button = $Add
+@onready var add_text = add_button.text
+
+func _ready():
+	update()
+
+func update(fix_focus: bool = false):
+	for c in actions_container.get_children():
+		c.queue_free()
+	
+	for e: InputEvent in value:
+		var description: String = InputManager.display_input_event(e)
+		var button := Button.new()
+		
+		button.text = description
+		button.pressed.connect(erase_event.bind(e))
+		actions_container.add_child(button)
+	
+	if fix_focus:
+		add_button.grab_focus()
+
+func erase_event(e: InputEvent):
+	value.erase(e)
+	update(true)
+	changed.emit()
+
+func _input(e: InputEvent):
+	if listening:
+		if e is InputEventKey or e is InputEventMouseButton or e is InputEventJoypadButton or e is InputEventJoypadMotion:
+			# Check if key was already added
+			for e2 in value:
+				if events_equal(e, e2): return
+			
+			value.append(e)
+			_on_add_pressed()
+			update()
+			changed.emit()
+
+func events_equal(e1: InputEvent, e2: InputEvent) -> bool:
+	if e1 is InputEventKey and e2 is InputEventKey:
+		return e1.physical_keycode == e2.physical_keycode
+	if (e1 is InputEventMouseButton and e2 is InputEventMouseButton) or (e1 is InputEventJoypadButton and e2 is InputEventJoypadButton):
+		return e1.button_index == e2.button_index
+	if e1 is InputEventJoypadMotion and e2 is InputEventJoypadMotion:
+		return e1.axis == e2.axis
+	return false
+
+func _on_add_pressed() -> void:
+	listening = not listening
+	add_button.text = tr("c.settings.input.press_any_key") if listening else add_text