Add input settings UI

1 files changed, 69 insertions, 0 deletions

diff --git a/client/menu/settings/input/input_value_node.gd b/client/menu/settings/input/input_value_node.gd
new file mode 100644
index 00000000..4436d97f
--- /dev/null
+++ b/client/menu/settings/input/input_value_node.gd
@@ -0,0 +1,69 @@
+# Hurry Curry! - a game about cooking
+# Copyright 2024 tpart
+#
+# This program is free software: you can redistribute it and/or modify
+# it under the terms of the GNU Affero General Public License as published by
+# the Free Software Foundation, version 3 of the License only.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU Affero General Public License for more details.
+#
+# You should have received a copy of the GNU Affero General Public License
+# along with this program.  If not, see <https://www.gnu.org/licenses/>.
+#
+extends VBoxContainer
+class_name InputValueNode
+
+var value: Array[InputEvent] = []
+var listening := false
+
+@onready var actions_container: VBoxContainer = $ActionsContainer
+@onready var add_button: Button = $Add
+@onready var add_text = add_button.text
+
+func _ready():
+	update()
+
+func update(fix_focus: bool = false):
+	for c in actions_container.get_children():
+		c.queue_free()
+	
+	for e: InputEvent in value:
+		var description: String
+		
+		if e is InputEventKey:
+			description = tr("%s (Keyboard)") % OS.get_keycode_string(e.physical_keycode)
+		elif e is InputEventMouseButton:
+			description = tr("Mouse button %s") % e.button_index
+		elif e is InputEventJoypadButton:
+			description = tr("%s (Joypad)") % e.button_index
+		elif e is InputEventJoypadMotion:
+			description = tr("Joypad axis %s") % [e.axis]
+		else:
+			description = tr("Other event")
+		
+		var button := Button.new()
+		button.text = description
+		button.pressed.connect(erase_event.bind(e))
+		actions_container.add_child(button)
+	
+	if fix_focus:
+		add_button.grab_focus()
+
+func erase_event(e: InputEvent):
+	value.erase(e)
+	update(true)
+
+func _input(e: InputEvent):
+	if listening:
+		if e is InputEventKey or e is InputEventMouseButton or e is InputEventJoypadButton or e is InputEventJoypadMotion:
+			value.append(e)
+			_on_add_pressed()
+			update()
+
+func _on_add_pressed() -> void:
+	listening = not listening
+	
+	add_button.text = tr("Press any key...") if listening else add_text